我的世界自动定时压缩备份文件夹、服务器文件、插件、地图文件

开一个我的世界服务器是非常不容易的,想必对各位minecraft服主、或者是一个需要定期备份服务器的人来说,服务器的数据安全无疑是非常重要的,无论是插件、地图,这些文件,都是会经常改动的,而且改动会有风险,最好的办法,就是每天都备份一次服务器,将需要备份的插件、地图,压缩起来。但每日备份总会有遗忘的时候,万一忘记了,而数据又遗失了,就得不偿失了,而且每日备份的确是也很麻烦。那么,今天IEcraft给各位服主带来了一个自动备份服务器插件、地图等资源的脚本,只需一次设置,即可定时备份,每日、每小时、甚至是每分钟,你都可以设置。无需下载任何程序,只需要有winrar或者7zip等压缩软件即可。

教程开始-代码

首先,我们将以下代码,放入一个txt文本中,再将核心信息,进行修改。

@echo off

rem echo 命令窗口字体颜色与清屏

color 0b & cls

echo;

title 定时自动备份文件BAT批处理脚本(添加到系统任务执行)

echo;程序初始化完成,正在进行压缩处理,请稍候...

echo;

cd /d "%~dp0"

rem echo 压缩程序所在安装位置决对路径

set "压缩程序=C:\Program Files\WinRAR_V5.61\WinRAR.exe"

rem echo 指定要备份的文件夹

set "备份目录=D:\Screenshot"

rem echo 备份文件所在存放位置 

set "存放目录=E:\Backup"

rem echo 程序初始化开始...

if not exist "%压缩程序%" (echo;"%压缩程序%" not found&goto end)

if not exist "%备份目录%" (echo;"%备份目录%" not found&goto end)

if not exist "%存放目录%" (md "%存放目录%")

rem echo 获取本地当前系统日期与系统时间

for /f "tokens=2 delims==" %%a in ('wmic OS get LocalDateTime /value ^|find "="') do set d=%%a

rem echo 去掉1点到9点前的空格,并将空格替换为0。

set h=%time:~0,2%

set h=%h: =0%

rem echo 命名规则(年月日_时分秒)

set today=%d:~0,4%%d:~4,2%%d:~6,2%_%h%%time:~3,2%%time:~6,2%

rem echo 正式生成文件名,并输出到屏幕窗口。

echo;压缩文件名称:%today%.Zip

rem echo 执行上述规则,并开始压缩文件。

rem echo a添加文件,-afzip压缩为zip格式(仅限WinRAR),-r递归,-ed不添加空目录,-ep1从名称中排除基本目录,命令行rar.exe程序无法压缩为zip文件。

"%压缩程序%" a -afzip -r -ed -ep1 "%存放目录%\%today%.zip" "%备份目录%\*"

:end

echo;

rem echo 文件压缩执行完成,并输出到屏幕窗口。

echo;文件压缩处理完成,请到文件备份目录查看。

echo;

rem echo 按任意键退出当前命令窗口。

pause

以下是需要修改的内容:

set "压缩程序=C:\Program Files\WinRAR_V5.61\WinRAR.exe"

rem echo 指定要备份的文件夹

set "备份目录=D:\Screenshot"

rem echo 备份文件所在存放位置

set "存放目录=E:\Backup"

只需要将以上内容修改为你想要的,即可执行。压缩程序就填winrar或者是其他压缩软件的的安装目录即可。

将以上脚本复制到txt文本中,更改信息以后,然后修改后缀为bat,你可以尝试运行一次本脚本,来测试是否正常使用。你设置的文件夹,会被压缩到你指定的文件夹,并且文件的名字是备份的日期,值得注意的是,部分数据库文件因被占用,会导致无法备份,这些文件会被自动跳过,所以不用理会,直接等它结束即可。

自动执行脚本

1、我们可以通过计划任务功能,来实现每天定时进行备份。首先,我们打开“控制面板”,找到“管理工具”

QQ截图20200414102430-1024x534.png

2、在“管理工具”中,找到“计划任务程序”

QQ截图20200414102548-300x179.png

3、在“计划任务中”,点击“创建基本任务”

QQ截图20200414102834-300x207.png

4、然后,名称描述可以根据自己的想法来填,这个是自定义的。

QQ截图20200414103519-300x230.png

5、选取执行频率,也就是你希望多久备份一次。

QQ截图20200414103805-300x222.png

6、在这里,选取每日备份的时间,日期不用管,只选择时间即可。一般推荐选择在晚上,例如凌晨等玩家少的时候,备份少占资源。

QQ截图20200414104007-300x233.png

7、选择“启动程序”

QQ截图20200414104040-300x237.png

8、下一步,点“浏览”,找到你刚刚制作好的脚本,选择它。

QQ截图20200414104128-300x232.png

9、选中好以后,点下一步,最后确认后信息,点完成,就可以看到计划任务被添加了。系统就会在你设定的时间每日帮你自动执行你需要压缩备份的文件到指定的文件夹。并且文件名是以日期保存的,非常的简单便捷。

QQ截图20200414104228-300x171.png

至此,教程就到这里结束啦!再也不用每天要惦记着备份这件事情,系统会帮你自动执行任务,希望可以帮到你!如果需要设置多个备份任务,例如要备份插件、某个地图,指定的数据,那就多复制几个脚本,多进行几个计划任务即可!推荐错峰备份,以免服务器CPU占用过高,影响服务器流畅程度。

转载请说明出处
百妖岛_我的世界服务器列表_MineCraft服务器联机平台_MC服务器大全 » 我的世界自动定时压缩备份文件夹、服务器文件、插件、地图文件